Page 368 - Chemical engineering design

343
DESIGN INFORMATION AND DATA
The Wilson equation is superior to the familiar Van-Laar and Margules equations (see
Volume 2, Chapter 11) for systems that are severely non-ideal; but, like other three suffix
equations, it cannot be used to represent systems that form two phases in the concentration
range of interest.
A significant advantage of the Wilson equation is that it can be used to calculate
the equilibrium compositions for multicomponent systems using only the Wilson
coefficients obtained for the binary pairs that comprise the multicomponent mixture. The
Wilson coefficients for several hundred binary systems are given in the DECHEMA
vapour-liquid data collection, DECHEMA (1977), and by Hirata (1975). Hirata gives
methods for calculating the Wilson coefficients from vapour liquid equilibrium
experimental data.
The Wilson equation is best solved using a short computer program with the Wilson
coefficients in matrix form, or by using a spreadsheet. A suitable program is given in
Table 8.9 and its use illustrated in Example 8.9. The program language is GWBASIC and
it is intended for interactive use. It can be extended for use with any number of components
by changing the value of the constant N in the first data statement and including the

Table 8.9. Program for Wilson equation (Example 8.15)
100 REM WILSON EQUATION
110 REM CALCULATES ACTIVITY COEFFICIENTS FOR MULTICOMPONENT SYSTEMS
120 PRINT ‘‘DATA STATEMENTS LINES 410 TO 450’’
130 READ N
140 REM MAT READ A
150 FOR I = 1 TO N
160 FOR J = 1 TO N
170 READ A(I, J)
180 NEXT J
190 NEXT I
200 PRINT ‘‘TYPE IN LIQUID COMPOSITION, ONE COMPONENT AT A TIME’’
210 FOR P=1 TO N
220 PRINT ‘‘X’’;P;‘‘?’’
230 INPUT X(P)
240 NEXT P
250 FOR K=1 TO N
260 Q1=0
270 FOR J=1 TO N
280 Q1=Q1+X(J)*A(K,J)
290 NEXT J
300 Q2=0
310 FOR I=1 TO N
320 Q3=0
330 FOR J=1 TO N
340 Q3=Q3+X(J)*A(I,J)
350 NEXT J
360 Q2=Q2+(X(I)*A(I,K))/Q3
370 NEXT I
380 G(K) = EXP(1-LOG(Q1)-Q2)
390 PRINT ‘‘GAMMA’’;K;‘‘=’’;G(K)
400 NEXT K
410 DATA 4
420 DATA 1,2.3357,2.7385,0.4180
430 DATA 0.1924,1,1.6500,0.1108
440 DATA 0.2419,0.5343,1,0.0465
450 DATA 0.9699,0.9560,0.7795,1
460 END