Page 110 - Chemical engineering design

94
CHEMICAL ENGINEERING
TABLE 3.2.
ENERGY 1, a simple energy balance program
10 REM SHORT ENERGY PROGRAM, REWRITTEN IN GWBASIC, MARCH 92
20 PRINT "HEAT BALANCE PROGRAM, BASIS kmol/h, TEMP K, DATUM 298 K"
30 PRINT "INPUT THE NUMBER OF COMPONENTS, MAXIMUM 10"
40 INPUT N1
50 PRINT "INPUT HEAT CAPACITY DATA FOR EQUATION A+BT+CT^2+DT^3"
60FORI= 1TON1
70 PRINT
80 PRINT "FOR COMPONENT"; I; "INPUT A, B, C, D, INCLUDING ANY ZERO VALUES"
90 INPUT A(I), B(I), C(I), D(I)
100 NEXT I
110 H4=H5=H6=Q1=0
120 PRINT "INPUT THE NUMBER OF FEED STREAMS"
130 INPUT S1
140FORI= 1TOS1
150 PRINT "FOR FEED STREAM"; I; "INPUT STREAM TEMP AND NUMBER OF COMPONENTS"
160 INPUT T1, N2
170 GOSUB 580
180 PRINT "STREAM SENSIBLE HEAT ="; H4; "kJ/h"
190 REM TOTAL SENSIBLE HEAT FEED STREAMS
200 H5 = H5 + H4
210 NEXT I
220 PRINT "INPUT NUMBER OF PRODUCT STREAMS"
230 INPUT S1
240FORI= 1TOS1
250 PRINT "FOR PRODUCT STREAM"; I; "INPUT STREAM TEMP AND NUMBER OF COMPONENTS"
260 INPUT T1, N2
270 GOSUB 580
280 PRINT "STREAM SENSIBLE HEAT ="; H4; "kJ/h"
290 REM TOTAL SENSIBLE HEAT PRODUCT STREAMS
300 H6 = H6 + H4
310 NEXT I
320 PRINT "INPUT THE NUMBER OF REACTIONS AND PHASE CHANGES"
330 INPUT N4
340 IF N4 = 0 THEN 450
350 PRINT "FOR EACH REACTION OR PHASE CHANGE INPUT THE HEAT OF REACTION"
360 PRINT "OR THE LATENT HEAT, kJ/kmol; AND QUANTITY INVOLVED kmol/h"
370 PRINT "REMEMBER: HEAT ENVOLVED:POSITIVE; HEAT ABSORBED:NEGATIVE"
380FORI= 1TON4
390 PRINT
400 PRINT "NEXT REACTION/PHASE CHANGE: INPUT VALUES"
410 INPUT R, F2
420 H7 = F2*R
430 Q1 = Q1 + H7
440 NEXT I
450 REM HEAT BALANCE
460 Q = H6-H5-Q1
470IFQ< 0THEN500
480 PRINT "HEATING REQUIRED ="; Q; "kJ/h"
490 GOTO 510
500 PRINT "COOLING REQUIRED ="; Q; "kJ/h"
510 PRINT "REPEAT CALCULATION WANTED ? TYPE Y FOR YES, N FOR NO"
520 INPUT P$
530 IF P$ = "N" THEN 560
540 PRINT "REPEAT CALCULATION"
550 GOTO 110
560 PRINT "CALCULATIONS FINISHED"
570 STOP
580 REM SUBROUTINE TO CALCULATE STREAM SENSIBLE HEATS
590 PRINT
600 PRINT "FOR EACH COMPONENT, INPUT THE COMPONENT NUMBER AND FLOW-RATE"
610 H4 = 0
620 FOR I1 = 1 TO N2
630 PRINT "NEXT COMPONENT"
640 INPUT J, F
650 REM HEAT CAPACITY EQUATION SPLIT OVER 2 LINES
660 H1 = A(J)*(T1-298) + B(J)*(T1^2-298^2)/2
670 H2 = C(J)*(T1^3-298^3)/3 + D(J)*(T1^4-298^4)/4
680 H3 = F*(H1+H2)
690 H4 = H4+H3
700 NEXT I1
710 RETURN